ЗАКЛЮЧЕНИЕ

В заключение можно сделать следующие выводы:

1) Разработана математическая модель, которая была решена с помощью метода пространства состояний.

2) Также разработана модель переходного процесса на основе матричных методов контурных токов и узловых потенциалов. Была проведена сравнительная характеристика этих двух методов для решения заданной модели.

3) Разработан алгоритм к программе решения модели. С помощью ЭВМ численно и графически проанализирована исходная модель.

ЛИТЕРАТУРА

1. Ажогин В.В., Згуровский М.З. Моделирование на цифровых, аналоговых и гибридных ЭВМ, 1983.

2. Влах И., Сингхал К. Машинные методы анализа и проэктирования электронных схем. М: Радио и связь, 1988.

3. Сиготский В.П. Математический аппарат инженера, 1975.

4. Гринчишин Я.Г., Ефимов В.И., Ломякович А.Н. Алгоритмы и программы на языке Basic, 1988.

ПРИЛОЖЕНИЕ 1

Блок-схема алгоритма

Листинг программы RUNKUT.BAS

10 PRINT "МЕТОД РУНГЕ-КУТТА ДЛЯ N УРАВНЕНИЙ "

20 INPUT "НАЧ.И КОН.ЗНАЧЕНИЕ АРГУМЕНТА(X,XK)";X,XK

30 INPUT "КОЛИЧЕСТВО ФУНКЦИЙ N";N

31 INPUT "ВВЕДИ КОЛИЧЕСТВО ТОЧЕК М";M

32 INPUT "ЧЕРЕЗ СКОЛЬКО ТОЧЕК ВЫВОДИТЬ НА ЭКРАН ?";Z1

40 DIM Y(6),Y1(6),K1(6),F(6),X(1500),FY(6,1500)

50 PRINT "НАЧ.ЗНАЧЕНИЯ ФУНКЦИЙ"

60 FOR I=1 TO N

61 PRINT "Y("I;

62 INPUT ")=";Y(I)

63 NEXT I

100 H=(XK-X)/M:MC=(XK-X)/20:Z9=0

101 FOR I=1 TO N

102 Y1(I)=Y(I):Y9(I)=0

103 NEXT I

110 FOR I=1 TO M

120 GOSUB 500

130 FOR L=1 TO N

131 K1(L)=F(L)

132 Y(L)=Y1(L)+F(L)/2

133 NEXT L

140 X=X+H/2

141 GOSUB 500

150 FOR L=1 TO N

151 K1(L)=K1(L)+2*F(L)

152 Y(L)=Y1(L)+F(L)/2

153 NEXT L

160 GOSUB 500

170 FOR L=1 TO N

171 K1(L)=K1(L)+2*F(L)

172 Y(L)=Y1(L)+F(L)

173 NEXT L

180 X=X+H/2

181 GOSUB 500

182 FOR L=1 TO N

183 Y(L)=Y1(L)+(K1(L)+F(L))/6

184 Y1(L)=Y(L)

185 NEXT L

186 X(I)=X

190 IF I MOD Z1=0 THEN PRINT X,

191 FOR L=1 TO N :FY(L,I)=Y(L)

192 IF I MOD Z1=0 THEN PRINT FY(L,I),

193 IF FY(L,I)>=Y9(L) THEN Y9(L)=FY(L,I)

194 NEXT L

195 IF I MOD Z1=0 THEN PRINT:Z=Z+1

200 IF Z=11 THEN 226 ELSE GOTO 228

226 Z=1:PRINT "ЖМИ ЛЮБУЮ КЛАВИШУ: *******"

227 IF LEN(INKEY$)=0 THEN 227 ELSE GOTO 228

228 NEXT I

229 PRINT "КОНЕЦ РАСЧЕТА ПЕРЕХОДНОГО ПРОЦЕССА: ЖМИ ЛЮБУЮ КЛАВИШУ."

230 IF LEN(INKEY$)=0 THEN 230 ELSE GOTO 231

231 FOR I=1 TO N

232 M(I)=Y9(I)/7:PRINT "МАСШТАБ ДЛЯ Y(";I;")";M(I);"ЕДЕНИЦ В 1 СМ"

233 IF I=1 THEN M(I)=30.5/M(I) ELSE M(I)=13.34/M(I)

234 NEXT I

235 PRINT "ДЛЯ ПРОДОЛЖЕНИЯ ЖМИ ЛЮБУЮ КЛАВИШУ."

240 PRINT " ФАЗОВЫЙ ПОРТРЕТ СИСТЕМЫ"

241 IF LEN(INKEY$)=0 THEN 241 ELSE GOTO 262

262 GOTO 1010

500 F(1)=H*(-1.8/.216*Y(1)+Y(2))

510 F(2)=H*(-3.6/.216*Y(1)+Y(3))

520 F(3)=H*(-.6/.216*Y(1)+1/.216)

530 RETURN

1010 SCREEN 2:KEY OFF:CLS

1030 LINE (0,0)-(639,199),7,B

1040 LINE (0,100)-(639,100),7

1050 LINE (320,0)-(320,199),7

1060 FOR I=1 TO M

1061 A=FY(1,I)*M(1)

1062 A%=CINT(A)+320

1070 FOR L=2 TO N

1073 B=FY(L,I)*M(L)

1074 B%=100-CINT(B)

1080 PSET(A%,B%),7

1090 NEXT L

1100 NEXT I

1110 Z$=INKEY$:IF LEN(Z$)=0 GOTO 1110

1120 SCREEN 0:CLS

2000 PRINT " РАЗВЕРТКА ПО ВРЕМЕНИ"

2010 PRINT "МАСШТАБ ПО ВРЕМЕНИ: ";MC;" СЕК В 1 СМ ЭКРАНА."

2020 PRINT "ЖМИ ЛЮБУЮ КЛАВИШУ ДЛЯ ПРОДОЛЖЕНИЯ ***********"

2030 IF LEN(INKEY$)=0 THEN 2030 ELSE 2040

2040 MC=30.5/MC

2050 SCREEN 2:CLS:KEY OFF

2080 LINE (0,0)-(639,199),7,B

2090 LINE (0,100)-(639,100),7

2091 M(1)=Y9(1)/7:M(1)=13.34/M(1)

2110 FOR I=1 TO M

2120 A=X(I)*MC

2130 A%=CINT(A)

2140 FOR L=1 TO N

2150 B=FY(L,I)*M(L)

2160 B%=100-CINT(B)

2170 PSET (A%,B%),7

2180 NEXT L

2190 NEXT I

2200 Z$=INKEY$:IF LEN(Z$)=0 GOTO 2200

2210 SCREEN 0:CLS

2230 END

ПРИЛОЖЕНИЕ 3

Результаты решения модели с помощью метода пространства состояний

а) Исходный случай:

R=10Ом; С=0,02Ф;

A₀=1(Ом×Ф); A₁=7(Ом×Ф); A₂=4,96(Ом×Ф)²; A₃=0,512(Ом×Ф).

Результат решения в виде числового материала:

МАСШТАБ ДЛЯ Y( 1 ) .2380673 ЕДИНИЦ В 1 СМ

МАСШТАБ ДЛЯ Y( 2 ) .0356338 ЕДИНИЦ В 1 СМ

МАСШТАБ ДЛЯ Y( 3 ) 5.863238E-02 ЕДИНИЦ В 1 СМ

ФАЗОВЫЙ ПОРТРЕТ СИСТЕМЫ

РАЗВЕРТКА ПО ВРЕМЕНИ

МАСШТАБ ПО ВРЕМЕНИ: 2.5 СЕК В 1 СМ

б) R=1Ом; С=0,02Ф;

A₀=1(Ом×Ф); A₁=0,7 (Ом×Ф); A₂=0,0496(Ом×Ф)²; A₃=0,064(Ом×Ф).

Результат решения в виде числового материала:

МАСШТАБ ДЛЯ Y( 1 ) 5.956024E-02 ЕДИНИЦ В 1 СМ

МАСШТАБ ДЛЯ Y( 2 ) 7.73615E-03 ЕДИНИЦ В 1 СМ

МАСШТАБ ДЛЯ Y( 3 ) 3.64474E-03 ЕДИНИЦ В 1 СМ

ФАЗОВЫЙ ПОРТРЕТ СИСТЕМЫ

РАЗВЕРТКА ПО ВРЕМЕНИ

МАСШТАБ ПО ВРЕМЕНИ: 2.5 СЕК В 1 СМ

ПРИЛОЖЕНИЕ 4

Результаты решения модели с помощью методов контурных токов и узловых потенциалов

Результат решения в виде числового материала:

МАСШТАБ ДЛЯ U_C1 .1426533 ЕДИНИЦ В 1 СМ

МАСШТАБ ДЛЯ U_C2 .1424898 ЕДИНИЦ В 1 СМ

МАСШТАБ ДЛЯ U_C3 .1423991 ЕДИНИЦ В 1 СМ

РАЗВЕРТКА ПО ВРЕМЕНИ

МАСШТАБ ПО ВРЕМЕНИ: 1.5 СЕК В 1 СМ