Задача 5.

Нарисовать фигуру "Снежинка" по следующему алгоритму: из одной точки – центра вырастают k кристалликов-отрезков длины r, свободный конец каждого из которых служит центром новой снежинки с длиной кристаллика-отрезка, в три раза меньшей r. Указанный процесс продолжается n раз. Ниже изображены снежинки при n=1, 2, 3, и k=6:

Решение.

Введем рекурсивную процедуру Snow, параметрами которой будут координаты центров снежинок x0, y0, радиус-длина r и глубина рекурсии n. Для размещения рисунка в области вывода, найдем начальный радиус по формуле: полагая dim=240, k=1/3. Получим: r=160/(1-1/3ⁿ). Чтобы величины cos(I*t) и sin(I*t) не вычислялись в цикле многократно (цикл содержится в теле рекурсивной процедуры), найдем указанные вещественные значения в процедуре Init и запомним их в массивах C и S. Это значительно ускорит работу программы.

Program Examp_31;

Uses crt, graph;

Const k=6; {Количество кристалликов-отрезков}

Var n:Integer;

C,S:Array[1..k] of real;

Procedure Graphinterface;

Var

driver, mode, error:Integer;

s:String;

Begin

driver:=detect;

s:=' ';

Initgraph(driver,mode,s);

error:=GraphResult;

if error<>GrOk then

begin

writeln(GraphErrorMsg(Error));

Halt(error)

end

end;

Procedure Init;

const t=2*pi/k;

var j:1..k;

begin

Write('Введите глубину рекурсии n

(от 1 до 6)');

Readln(n);

for j:=1 to k do

begin

C[j]:=cos(j*t);

S[j]:=sin(j*t);

end;

end; {Init}

Procedure Snow(x0,y0,r,n:Integer);

var x,y,i:Integer;

begin

for i:=1 to k do

begin {SetColor(16-i);(16-n)}

x:=x0+Round(r*C[i]); {+10}

y:=y0-Round(r*S[i]); {-10}

Line(x0,y0,x,y);

if n>1 then Snow(x,y,r div 3,n-1);

end;

end; {Snow}

begin

Init;Graphinterface;

Snow(320,240,Round(160/(1-1/(Exp(n*Ln(3))))),n);

Readln; CloseGraph;

End.