ЗАДАНИЕ 1

1. Перейдите на новый лист и назовите его «Число».

2. В ячейку А1 введите произвольное семизначное вещественное число.

3. В ячейки А2:Н2 ввести данные из вышеприведённой таблицы.

4. В ячейках А3:G3 рассчитывается количество миллионов, сотен тысяч, десятков тысяч, и т.д. в заданном числе. Эта процедура выполняется с использованием встроенной математической функции ОТБР.

ОТБР(число;число_разрядов)

Число — усекаемое число.

Число_разрядов — число, определяющее точность усечения. Значение по умолчанию 0 (нуль).

В ячейке А3 - =ОТБР(A1/1000000;0),

В ячейке В3 - =ОТБР(A1/100000;0) и т.д.

В ячейке G3 - =ОТБР(A1/1;0).

5. В ячейке Н3 формируется количество дробной части числа - =ОКРУГЛ((A1-G3)*100;0).

6. В ячейках А4:G4 формируются цифры, стоящие в каждом разряде числа:

В ячейке А4 - =А3

В ячейке В4 - =B3-A3*10

В ячейке С4 - = C3-B3*10 и т.д.

7. Т.к. дробная часть числа в финансовых документах обычно не пишется прописью, то значение ячейки Н3 непосредственно используется в формировании выходной информации. Если дробная часть числа не больше 9, то перед числом добавляется 0 (нуль). Эта операция выполняется в ячейке Н4: =ЕСЛИ(H3<=9;0;"").

8. В ячейках А5:С5 происходит первоначальное сравнение соответствующего разряда числа с нулём и формирование на основе этого сравнения прописного числа:

А5 - =ЕСЛИ(A4=0;"";ЕСЛИ(A4=1;"один";A6))

В5 - =ЕСЛИ(B4=0;"";ЕСЛИ(B4=1;"сто";B6))

С5 - =ЕСЛИ(C4=0;"";ЕСЛИ(C4=1;ЕСЛИ(D4=0;"десять";"");C6))

9. Блоки А6:А12, В6:В12, С6:С12 формируются аналогично написанию дня недели прописью (лаб.раб. 3). Так в ячейках

А6 - =ЕСЛИ(A4=2;"два";A7)

А7 - =ЕСЛИ(A4=3;"три";A8) и т.д.

А12 - =ЕСЛИ(A4=8;"восемь";"девять").

10. Формирование ячеек D5:D12 связано с особенностями образования числа для значений с 11 до 19.

D5 – =ЕСЛИ(D4=1;ЕСЛИ(C4=1;"одиннадцать";"одна");D6)

D6 – =ЕСЛИ(D4=2;ЕСЛИ(C4=1;"двенадцать";"две");D7) и т.д.

D12 - =ЕСЛИ(D4=8;ЕСЛИ(C4=1;"восемнадцать";"восемь");D13).

11. Ячейки Е5:Е12 формируются аналогично В5:В12.

12. Ячейки F5:F12 формируются аналогично C5:C12.

13. Ячейки G5:G12 формируются аналогично D5:D12.

14. В ячейках А14 и D14 формируются соответствующие названия разрядов:

=ЕСЛИ(A4=0;""; ЕСЛИ(ПРАВСИМВ(A5;1)="а";"миллиона"; ЕСЛИ(ПРАВСИМВ(A5;1)="е";"миллиона"; ЕСЛИ(ПРАВСИМВ(A5;1)="и";"миллиона"; ЕСЛИ(ПРАВСИМВ(A5;1)="н";"миллион";"миллионов")))))

=ЕСЛИ(B4+C4+D4=0;""; ЕСЛИ(ПРАВСИМВ(D5;1)="а";"тысяча"; ЕСЛИ(ПРАВСИМВ(D5;1)="е";"тысячи"; ЕСЛИ(ПРАВСИМВ(D5;1)="и";"тысячи";"тысяч"))))

15. В ячейке G14 формируется единица измерения:

ЕСЛИ(A4+B4+C4+D4+E4+F4+G4=0;"Нуль рублей"; ЕСЛИ(ПРАВСИМВ(G5;1)="н";"рубль"; ЕСЛИ(ПРАВСИМВ(G5;1)="а";"рубля"; ЕСЛИ(ПРАВСИМВ(G5;1)="е";"рубля"; ЕСЛИ(ПРАВСИМВ(G5;1)="и";"рубля";"рублей")))))

16. В ячейке А15 формируется итоговая информация с помощью известной нам функции

=СЦЕПИТЬ(A5;" ";A14;" ";B5;" ";C5;" ";D5;" ";D14;" ";E5;" ";F5;" ";G5;" ";G14;" ";H4;H3;" коп.")

17. В ячейке А16 из текста удаляются лишние пробелы с помощью текстовой функции

=СЖПРОБЕЛЫ(A15).

18. Ячейки А17:А21 предназначены для написания числа с заглавной буквы. Используются встроенные функции категории текстовые.

В ячейке А17 выделяется самый левый: =ЛЕВСИМВ(A16;1)

Ячейка А18 назначает для выделенного символа прописную букву: =ПРОПИСН(A17).

В А19 подсчитывается, сколько символов находится в сформированной строке без лишних пробелов: =ДЛСТР(A16).

В ячейке А20 из итоговой строки извлекаются все символы, кроме первого
=ПРАВСИМВ(A16;A19-1).

В ячейке А21 формируется итоговая строка – число прописью с заглавной буквы
=СЦЕПИТЬ(A18;A20).